статистика, количество символов без пробелов

[Vovans]

Как узнать кол-во символов в документе без пробелов?

Все подвернувшиеся редактоы/процессоры это умеют (скажeм, gedit, abiword etc), а вот монстр ОО...

тут был:

http://qa.openoffice.org/issues/show_bug.cgi?id=10356

и это читал:

Имеется элегантное решение - делаем "Найти все" для пробела, Закрыть, Сервис - Количество слов и получаем искомую величину

выход, но несколько неудобно Никому не попадались более удобные решения этого вопроса? Вот бы макрос такой......... ((

[Vovans]

на faq {Ссылка устарела. Новая ссылка: http://wiki.services.openoffice.org/wiki/RU/kb} тоже был.... Тишина ((

[rail]

Еще не реализовано, но даже в формате ODF предусмотрено.

[Vovans]

да уж )

[dr.Faust]

Еще не реализовано, но даже в формате ODF предусмотрено.

А можно поподробнее в этом месте?

[rail]

Вот что предусмотрено для статистики текста в формате:
meta:page-count
meta:table-count
meta:draw-count
meta:image-count
meta:object-count
meta:ole-object-count
meta:paragraph-count
meta:word-count
meta:character-count
meta:row-count
meta:frame-count
meta:sentence-count
meta:syllable-count
meta:non-whitespace-character-count

[Mike]

meta:non-whitespace-character-count

кажется это то что нужно

[Vovans]

кажется это то что нужно

И? Решения проблемы всё равно нет?

[lemonjoe]

Макрос есть! Мне предоставил его юзер по имени SkazochNick, за что выражаю ему персональное спасибо!
Инструкция:

Установка (ручная):

0. Запускай OO Writer
У меня 3.1, но должно быть так же все

1. Сервис->Макросы->Управление макросами->OpenOffice Basic
2. Макрос из "Мои макросы" -> Standart (выделить) -> Управление
3. Здесь "Новый модуль". Называй его как хочешь, можешь как я
"lettercounter". Выделяй его и "Редактировать"
4. Откроется редактор. Он дурной. Так что все что там есть сноси и
копипасть вот это:

=========================== скопипастить ниже =================================
REM  *****  BASIC  *****

Sub Main

' для Lemojoe:
' Имеется текст. Необходим вывод на информационной табличке статистических данных:
' количество знаков с пробелами, количество знаков без пробелов. Чтобы подсчет
' можно было произвести в любой момент работы над документом.

   Dim doc as object
   Dim controller as object
   Dim textviewcursor as object ' всякие объекты там... не важно
   Dim letters as String ' выделенная строка с текстом
   Dim gap as Integer ' число пробелов
   Dim cursign as String ' текущий значок
   dim break as Integer ' число переносов строк
   Dim i as Integer ' счетчик
   gap = 0
   break = 0

   ' получаем current document -> controller -> view cursor
   doc = ThisComponent
   controller = doc.getCurrentController()
   textviewcursor = controller.getViewCursor()


   letters = textviewcursor.getString ' забираем выделенный текст

   For i = 1 To Len(letters)

       cursign = Mid (letters, i, 1)

       If cursign = chr(32) Then ' Считаем пробелы
           gap = gap + 1 ' один да один - два

       ElseIf cursign = chr(10) Or cursign = chr(9)  Then ' Считаем переносы строк
           break = break + 1
       End If

   Next
   msgbox "Всего знаков: " & Len(letters) - break & chr(13) & "Знаков без пробелов: " & Len(letters) - gap - break

End Sub
=========================== скопипастить выше =================================

5. Файл->Сохранить/Закрыть
6. Теперь вставь текст в Writer, выдели его (Ctrl+A).
Сервис->Макросы->Выполнить макрос
7. В "Библиотека"->Standart->lettercounter(Main)-> Выполнить

Если есть необходимость, то макрос через Сервис-Настройки выносится на панель. Ему присваивается понятное имя и значок. Работает хорошо, единственное, для того, чтобы подсчитать количество символов, необходимо выделить кусок текста. Ну, или весь текст. 

[lemonjoe]

Да, еще забыл отметить: количество знаков в таблицах не считает. Если кто-нибудь сможет усовершенствовать макрос, его автор был бы только рад.  

[фывао]

Так работает везде:

Код:

Sub Main
Dok = ThisComponent
Poisk = Dok.createSearchDescriptor
Poisk.SearchRegularExpression = TRUE
Poisk.SearchString = "$" 'абзацы
A = Dok.findAll(Poisk).Count
Poisk.SearchString = "\n" 'обрыв строки
B = Dok.findAll(Poisk).Count
Poisk.SearchString = "\t" 'табуляция
C = Dok.findAll(Poisk).Count
Poisk.SearchString = " " 'пробел
D = Dok.findAll(Poisk).Count
p = chr(13)
msgbox cStr(A)+ " - абзацы "+p+cStr(B)+ " - обрывы строки "+p+cStr(C)+ " - табуляции "+p+cStr(D)+ " - пробелы " , 64
End Sub

Можно также из общего числа символов (которое можно либо сосчитать тем же способом что и выше, либо взять сразу Dok.CharacterCount) вычесть число пробелов.

[Федор]

А кто-нибудь может скрестить оба макроса? К сожалению, я не умею программировать.

[фывао]

Код:

Sub Main
Dok = ThisComponent
Poisk = Dok.createSearchDescriptor
Poisk.SearchRegularExpression = TRUE
Poisk.SearchString = "$" 'абзацы
A = Dok.findAll(Poisk).Count
Poisk.SearchString = "\n" 'обрыв строки
B = Dok.findAll(Poisk).Count
Poisk.SearchString = "\t" 'табуляция
C = Dok.findAll(Poisk).Count
Poisk.SearchString = " " 'пробел
D = Dok.findAll(Poisk).Count
p = chr(13)
E = Dok.CharacterCount 'всего символов
msgbox cStr(E)+ " - всего символов "+p+cStr(E-D)+ " - символов без пробелов "+p+cStr(A)+ " - абзацы "+p+cStr(B)+ " - обрывы строки "+p+cStr(C)+ " - табуляции "+p+cStr(D)+ " - пробелы " , 64
End Sub

[lemonjoe]

фывао, ваш макрос не считает выделенную часть документа.  К сожалению.

[фывао]

Тогда вот:

Код:

Sub Main
Dok = ThisComponent
Poisk = Dok.createSearchDescriptor
Poisk.SearchRegularExpression = TRUE
Poisk.SearchAll = FALSE
Poisk.SearchString = "$" 'абзацы
A = Dok.findAll(Poisk).Count
Poisk.SearchString = "\n" 'обрыв строки
B = Dok.findAll(Poisk).Count
Poisk.SearchString = "\t" 'табуляция
C = Dok.findAll(Poisk).Count
Poisk.SearchString = " " 'пробел
D = Dok.findAll(Poisk).Count
p = chr(13)
Poisk.SearchString = "." 'все символы
E = Dok.findAll(Poisk).Count 'всего символов
msgbox cStr(E)+ " - всего символов "+p+cStr(E-D)+ " - символов без пробелов "+p+cStr(A)+ " - абзацы "+p+cStr(B)+ " - обрывы строки "+p+cStr(C)+ " - табуляции "+p+cStr(D)+ " - пробелы " , 64
End Sub

[smaharbA]

колонтитулы и прочие блоки и врезки как считать ?

[фывао]

Не знаю...
Последний вариант тоже не считает символы в выделенном тексте, несмотря на SearchAll=FALSE (как этим пользоваться?).
Тогда вот вариант.

Код:

Sub Main
document   = ThisComponent.CurrentController.Frame
dispatcher = createUnoService("com.sun.star.frame.DispatchHelper")
dispatcher.executeDispatch(document, ".uno:Copy", "", 0, Array())
NDok = StarDesktop.loadComponentFromURL( "private:factory/swriter", "_blank", 0, Array())
Ndocument   = NDok.CurrentController.Frame
Dim args1(0) as new com.sun.star.beans.PropertyValue
args1(0).Name = "SelectedFormat"
args1(0).Value = 1
dispatcher.executeDispatch(Ndocument, ".uno:ClipboardFormatItems", "", 0, args1())

Poisk = NDok.createSearchDescriptor
Poisk.SearchRegularExpression = TRUE
Poisk.SearchString = "$" 'абзацы
A = NDok.findAll(Poisk).Count
Poisk.SearchString = "\n" 'обрыв строки
B = NDok.findAll(Poisk).Count
Poisk.SearchString = "\t" 'табуляция
C = NDok.findAll(Poisk).Count
Poisk.SearchString = " " 'пробел
D = NDok.findAll(Poisk).Count
p = chr(13)
E = NDok.CharacterCount 'всего символов
msgbox cStr(E)+ " - всего символов "+p+cStr(E-D)+ " - символов без пробелов "+p+cStr(A)+ " - абзацы "+p+cStr(B)+ " - обрывы строки "+p+cStr(C)+ " - табуляции "+p+cStr(D)+ " - пробелы " , 64
NDok.setModified(FALSE)
NDok.close(TRUE)
End Sub

[фывао]

Вот ещё вариант, который работает с выделенным текстом (правда, выделен должен быть один участок, а иначе символы будут сосчитаны от начала первого до конца последнего).

Код:

Dim Dok, Tx, Poisk, VK As Object

Sub Main
Dok = ThisComponent
Tx = Dok.Text
Poisk = Dok.createSearchDescriptor
Poisk.SearchRegularExpression = TRUE
VK = Dok.CurrentController.ViewCursor
' Poisk.SearchString = "\t" 'табуляция
' C = PoiskV
Poisk.SearchString = " " 'пробел
D = PoiskV
Poisk.SearchString = "." 'все символы
E = PoiskV 'всего символов
p = chr(13)
msgbox cStr(E)+ " - всего символов "+p+cStr(E-D)+ " - символов без пробелов " , 64 '+p+cStr(C) + " - табуляции " , 64
End Sub
'------------------------------------------------------
Function PoiskV As Integer
Dim k As Integer
oT = Tx.createTextCursorByRange(VK.Start,FALSE)
oK = Tx.createTextCursorByRange(VK.End,FALSE)
oT = Dok.findNext(oT.End, Poisk)
If isNull(oT) then
PoiskV=0
Exit Function
Endif
While not isNull(oT) and Tx.compareRegionEnds(oT,oK)>0
oT = Dok.findNext(oT.End, Poisk)
k=k+1
Wend
PoiskV=k
End Function

[smaharbA]

а чем плох найти+заменить ?

[smaharbA]

по поводу выделенного - селект это объект и в нем можно искать все

[Федор]

Если в документе только текст, то все гут. Если еще и таблица или просто в таблице, то:

Ошибка времени выпoлнeния BASIC.
Вызвано исключение
Type: com.sun.star.lang.IllegalArgumentExceptIOn
           Message: .

Это я о последнем коде.

Код в 12-ом посте (без выделения) работает как часы. В принципе, количество знаков в выделении мне нужно очень редко. Так что огромное спасибо, уже использую.

[smaharbA]

есть чарсетС, конечно в МСО несколько иначе, но и тут есть

[фывао]

smaharbA, если есть немного времени, помогите разобраться, пожалуйста.

Вот по теме: http://www.oooforum.org/forum/viewtopic.phtml?t=40529&highlight=searchall+selection
Почему-то не работает макрос, который приведён на том же форуме: http://www.oooforum.org/forum/viewtopic.phtml?t=20103&highlight=replaceall+selection (точнее, работает, но если искать абзацы - то не работает). Ещё тут пример: http://www.pitonyak.org/AndrewMacro.odt пункт 7.14.2)

В общем, всё что у меня получилось - выше приведено, и больше ничего не могу.

[smaharbA]

т.е. не работает ?

Код:

P = ThisComponent.createSearchDescriptor
P.SearchRegularExpression = TRUE
P.SearchString = "$"
msgbox ThisComponent.findAll(p).count

в целом мене ООо интересен только для флуда ))) (правдо)
(и несколько из насколько то профессионального интереса, он есть как печатная машинка на некоторых (ранее на привелигирующих) машинках)

не поддерживаемое мнение мое - конструктора объектности ООо злоупотребляют анашой (холивар) )))

в данное время не имею возможности обдумать проблему
(правдо вот после такого - должны сказать - пустобрех )

[Федор]

Что такое "привелигирующих". Вообще, о чем был предыдущий пост?
У нас язык общения русский или я не по адресу попал?
Почему каким-то диким белым стихом?
Все же, кто может выложить код, работающий для выделения без ошибки?

[smaharbA]

зачем ?

[Федор]

Заканчивай флуд, остроумный.

[Nick]

2 Федор:

smaharbA часто страдает неадекватной реакцией и ответами не в тему. Не обращайте на него внимания.

[Nick]

зачем ?

Когда говоришь, что думаешь, думай, что говоришь!

[smaharbA]

Nick - хоть один ответ не по теме Вы лично встречали ? Другое дело в понимании